
APData2: Merging two datasets after EXCEL import.

Prepared by Wendy Bergerud

Last Saved: 31 October 2003
This annotated program will explore some aspects of working with SAS datasets.  As an example, we will take the two EXCEL spreadsheets imported into SAS in APData1 and merge them in preparation for data analysis.

1. Importing the EXCEL spreadsheets

The first step is to import the two spreadsheets into SAS datasets:

*** Importing two EXCEL spreadsheets;
PROC IMPORT OUT= WORK.First 

  DATAFILE= "FirstVariable.XLS" 

  DBMS=EXCEL2000 REPLACE; RANGE="No_blank$A8:E32"; GETNAMES=YES;

RUN;

PROC IMPORT OUT= WORK.second 

  DATAFILE= "Second_variable.XLS" 

  DBMS=EXCEL2000 REPLACE;  RANGE="With Blank$A6:D43"; GETNAMES=YES;

RUN;

The ViewColumns windows for these two data sets are:

2. Merging datasets and renaming variables

We want to merge these two datasets so that we can analyse y1 and y2 together.  Individual observations are identified by block, eco zone and treatment and so we will merge by these variables.  But we weren’t consistent when we set up the EXCEL spreadsheets and so we have some variable or column names that we don’t want, and the names aren’t the same for both datasets.  Further the First dataset has a variable name of _COL3 for y1.  Before merging these two datasets into one we have to:

· Sort both datasets the same way so that they can be merged.

· Rename the variables so that they match in both datasets.

There are at least three ways we can do this.

1) Sort and Rename during Merge: We can sort the two datasets with the following code:

*** Sorting data before the merge;
proc sort data=first;  by block _col1 treat_; run;

proc sort data=second; by block zone trt;     run;

and then merge them with the following code: 

*** Merging the two datasets;
data third;

  merge first  (rename = (_col1 = zone treat_ = treat  _col3 = y1))

        second (rename = (trt = treat)) ;

  by block zone treat;

run; 

Note that the names of the by variables are different for the two sort routines.  We can rename the variables in the First dataset AND merge it with the Second data set in one data step, by using the rename option in the merge statement.  The old variable name is listed first while the new name is given after the equal sign.  

2) Renaming during Sort and then Merge: Another option would be to rename the variables during the sort.  Notice that the old names must be used in the by statements.

*** Sorting data and renaming variables before the merge;
proc sort data=first 

  out = first  (rename = (_col1 = zone treat_ = treat  _col3 = y1));

  by block _col1 treat_; run;

proc sort data=second out = second (rename = (trt = treat)); 

  by block zone trt;     run;

*** Merging the two datasets;
data third;

  merge first second;  by block zone treat; run;

3) Renaming in the ViewColumns Window before Merging: A third option is to right click on the column name in the ViewColumns window and choose the rename option.  This would have to be done for each variable, and redone all over again should the EXCEL file need to be imported again (such as after fixing some problems with the data).

3. Problems with the Merge

Regardless of the merging methods chosen, we now have a merged dataset called Third.  Part of the ViewTable is shown below.

Notice that the column headings and labels for the common variables are those from the First dataset which was listed first in the merge statement.  The variables in the First dataset but not the Second are listed next and then those from the Second dataset are listed last
.  The order the datasets are listed in the merge statement can have quite an effect on the final dataset.

When we look at the data we see that we have some problems
:

1) We don’t need all the lines with no data and so might want to delete them.

2) And, even worse, our observations did not properly merge!

While we renamed the TREAT_ and TRT to a common name of treat, the values in the two spreadsheets are different.  In the First dataset they were all capitalized while only the first letter was capitalized in the Second dataset.  These are seen as different values by SAS and so were not merged as we wanted
.  We were “lucky” that the eco zone values were consistent between datasets, or we might have also had the same problem with that variable.

There are a number of possible solutions for the bad matching:

1) In EXCEL: We could go back to one of the spreadsheets and change the values there.  One way to do this would be to highlight the column and then use the find/replace option from the Edit drop-down menu (or directly through CTRL H) to change all values of ‘BURN’ to ‘Burn’, etc.

2) Character Functions: Use SAS functions lowcase or upcase to make all the values lower or upper case.  This would have to be done BEFORE the datasets were merged.  The following code using upcase would do the trick.  Since the data in First is already in upper case, only one dataset has to be changed, while both would need to be changed if we used the lower case function.

*** Changing the values of treat in the Second dataset;
data second; set second; treat = upcase(treat); run;

*** Merging the two datasets;
data third;  merge first second;  by block zone treat; run; 

3) Put function with formats: We could use Proc Format to define the common values that we want and then use the put function to make these formatted values the values of treat
.  This method is more flexible since we can choose any values to replace the old values. 

First, we define the formatted values:

proc format; 

  value $ trt 'BURN' = 'Burn' 'MANUAL' = 'Manual' 'MOUND' = 'Mound'; run;

Then we use the put function to change the old values of treat to the values in the format table, and then merge the two datasets.

*** Changing the values of treat;
data first; set first; treat = put(treat, $trt.); run;

*** Merging the two datasets;
data third;  merge first second;  by block zone treat; run; 

We also wanted to delete the extra observations with missing values from the Second dataset.  There are at least three ways to do this:

1) In EXCEL: Delete these observations from the spreadsheet before importing into SAS.

2) Before Merging: Delete these observations in an earlier data step, such as when capitalizing the treat values:

*** Changing the values of treat in the Second dataset;
data second; set second; treat = upcase(treat); if block ne .; run;

3) During the Merge: Delete these observations during the merge

*** Merging the two datasets;
data third;

  merge first second;  by block zone treat; 

  if treat ne ' ';

run; 

Note on Missing Values: Since block was a numeric value its missing value is denoted by a ‘.’, but treat is a text or character value and its missing value is denoted by a blank: ‘ ’.

The final dataset now looks the way we wanted it to:

Appendix: Programs showing two different approaches.

title "APData2 - Merging two datasets";

*** Importing two EXCEL spreadsheets;
PROC IMPORT OUT= WORK.First 

  DATAFILE= "FirstVariable.XLS" 

  DBMS=EXCEL2000 REPLACE; RANGE="No_blank$A8:E32"; GETNAMES=YES;

RUN;

PROC IMPORT OUT= WORK.second 

  DATAFILE= "Second_variable.XLS" 

  DBMS=EXCEL2000 REPLACE;  RANGE="With Blank$A6:D43"; GETNAMES=YES;

RUN;

*** Version 1: Sorting data before the merge and changing treat to all

               upper case;
proc sort data=first; by block _col1 treat_; run;

proc sort data=second; by block zone trt;    run;

*** Changing the values of treat in the Second dataset;
data second; set second; trt = upcase(trt); run;

*** Merging the two datasets;
data third;

  merge first  (rename = (_col1 = zone treat_ = treat  _col3 = y1))

        second (rename = (trt = treat)) ;

  by block zone treat ;  if block ne '.';  run;

*** Version 2: Renaming during the sort and using the PUT function for 

               the treat values;
*** Sorting data and renaming variables before the merge;
proc sort data=first out = first  (rename = (_col1 = zone treat_ = treat  _col3 = y1));

  by block _col1 treat_; run;

proc sort data=second out = second (rename = (trt = treat)); by block zone trt;    run;

*** Format values to match data in First to that in Second;
proc format; value $ trt 'BURN' = 'Burn' 'MANUAL' = 'Manual' 'MOUND' = 'Mound'; run;

*** Changing the values of treat;
data first; set first; treat = put(treat, $trt.); run;

*** Merging the two datasets;
data third;

  merge first second;  by block zone treat ;   if treat ne ' ';  run;

�











� Any variable in both datasets not included in the by statement would have the values of the variable in the last listed dataset replace the values of the variable in the first listed dataset.  Order matters here.


� We might have also noticed that there was problem if we looked closely at the SAS log:


NOTE: There were 24 observations read from the data set WORK.FIRST.


NOTE: There were 37 observations read from the data set WORK.SECOND.


NOTE: The data set WORK.THIRD has 61 observations and 5 variables.


We should wonder why there are 37 observations in Second when we should have 24 and then why the merged dataset has 61 observations instead of 24!


� This is one reason why I prefer to work with numeric values for categorical variables and then use PROC FORMAT to label the values for the output.


� Note that formats by themselves don’t work – they change the values of variables when it is printed or looked at in the ViewTable, but does not change the internal variable values.

